Как да използвам функцията Excel VLOOKUP -

Обобщение

VLOOKUP е функция на Excel за търсене на данни в таблица, организирана вертикално. VLOOKUP поддържа приблизително и точно съвпадение и заместващи символи (*?) За частични съвпадения. Справочните стойности трябва да се появят в първата колона на таблицата, предадена във VLOOKUP.

Предназначение

Търсете стойност в таблица чрез съвпадение в първата колона

Върната стойност

Съответстващата стойност от таблица.

Синтаксис

= VLOOKUP (стойност, таблица, col_index, (range_lookup))

Аргументи

стойност - Стойността, която трябва да се търси в първата колона на таблица.
table - таблицата, от която да се извлече стойност.
col_index - Колоната в таблицата, от която да се извлече стойност.
range_lookup - (по избор) TRUE = приблизително съвпадение (по подразбиране). FALSE = точно съвпадение.

Версия

Excel 2003

Бележки за употреба

VLOOKUP е функция на Excel за получаване на данни от таблица, организирана вертикално. Справочните стойности трябва да се появят в първата колона на таблицата, предадена във VLOOKUP. VLOOKUP поддържа приблизително и точно съвпадение и заместващи символи (*?) За частични съвпадения.

V е за вертикална

Целта на VLOOKUP е да получи информация от таблица, организирана по този начин:

Използвайки номера на поръчката в колона Б като стойност за справка, VLOOKUP може да получи идентификатора на клиента, сумата, името и състоянието за всяка поръчка. Например, за да получите името на клиента за поръчка 1004, формулата е:

=VLOOKUP(1004,B5:F9,4,FALSE) // returns "Sue Martin"

За хоризонтални данни можете да използвате HLOOKUP, INDEX и MATCH или XLOOKUP.

VLOOKUP се основава на номера на колони

Когато използвате VLOOKUP, представете си, че всяка колона в таблицата е номерирана, започвайки отляво. За да получите стойност от определена колона, предоставете подходящото число като „индекс на колона“. Например индексът на колоната за извличане на първо име по-долу е 2:

Фамилното име и имейл могат да бъдат извлечени с колони 3 и 4:

=VLOOKUP(H3,B4:E13,2,FALSE) // first name =VLOOKUP(H3,B4:E13,3,FALSE) // last name =VLOOKUP(H3,B4:E13,4,FALSE) // email address

VLOOKUP изглежда само правилно

VLOOKUP може да гледа само надясно. Данните, които искате да извлечете (стойности на резултатите), могат да се появят във всяка колона вдясно от справочните стойности:

Ако трябва да търсите стойности вляво, вижте ИНДЕКС и СЪВПАДАНЕ, или XLOOKUP.

Точно и приблизително съвпадение

VLOOKUP има два режима на съвпадение, точно и приблизително. Името на аргумента, който контролира съвпадението, е " range_lookup ". Това е объркващо име, защото изглежда, че има нещо общо с диапазоните от клетки като A1: A10. Всъщност думата "диапазон" в този случай се отнася до "диапазон от стойности" - когато range_lookup е TRUE, VLOOKUP ще съответства на диапазон от стойности, а не на точна стойност. Добър пример за това е използването на VLOOKUP за изчисляване на оценки.

Важно е да се разбере, че по подразбиране range_lookup е TRUE, което означава, че VLOOKUP ще използва приблизително съвпадение по подразбиране, което може да бъде опасно. Задайте range_lookup на FALSE, за да принудите точното съвпадение:

=VLOOKUP(value, table, col_index) // approximate match (default) =VLOOKUP(value, table, col_index, TRUE) // approximate match =VLOOKUP(value, table, col_index, FALSE) // exact match

Забележка: Можете също да предоставите нула (0) вместо FALSE за точно съвпадение.

Точно съвпадение

В повечето случаи вероятно ще искате да използвате VLOOKUP в режим на точно съвпадение. Това има смисъл, когато имате уникален ключ, който да използвате като справочна стойност, например заглавието на филма в тези данни:

Формулата в H6 за намиране на Година , базирана на точно съвпадение на заглавието на филма, е:

=VLOOKUP(H4,B5:E9,2,FALSE) // FALSE = exact match

Приблизително съвпадение

In cases when you want the best match , not necessarily an exact match , you'll want to use approximate mode. For example, below we want to look up a commission rate in the table G5:H10. The lookup values come from column C. In this example, we need to use VLOOKUP in approximate match mode, because in most cases an exact match will never be found. The VLOOKUP formula in D5 is configured to perform an approximate match by setting the last argument to TRUE:

=VLOOKUP(C5,$G$5:$H$10,2,TRUE) // TRUE = approximate match

VLOOKUP will scan values in column G for the lookup value. If an exact match is found, VLOOKUP will use it. If not, VLOOKUP will "step back" and match the previous row.

Note: data must be sorted in ascending order by lookup value when you use approximate match mode with VLOOKUP.

First match

In the case of duplicate values, VLOOKUP will find the first match when the match mode is exact. In screen below, VLOOKUP is configured to find the price for the color "Green". There are three entries with the color Green, and VLOOKUP returns the price for the first entry, $17. The formula in cell F5 is:

=VLOOKUP(E5,B5:C11,2,FALSE) // returns 17

Wildcard match

The VLOOKUP function supports wildcards, which makes it possible to perform a partial match on a lookup value. For instance, you can use VLOOKUP to retrieve values from a table after typing in only part of a lookup value. To use wildcards with VLOOKUP, you must specify exact match mode by providing FALSE or 0 for the last argument, range_lookup . The formula in H7 retrieves the first name, "Michael", after typing "Aya" into cell H4:

=VLOOKUP($H$4&"*",$B$5:$E$104,2,FALSE)

Read a more detailed explanation here.

Two-way lookup

Inside the VLOOKUP function, the column index argument is normally hard-coded as a static number. However, you can also create a dynamic column index by using the MATCH function to locate the right column. This technique allows you to create a dynamic two-way lookup, matching on both rows and columns. In the screen below, VLOOKUP is configured to perform a lookup based on Name and Month. The formula in H6 is:

=VLOOKUP(H4,B5:E13,MATCH(H5,B4:E4,0),0)

For more details, see this example.

Note: In general, INDEX and MATCH is a more flexible way to perform two-way lookups.

Multiple criteria

The VLOOKUP function does not handle multiple criteria natively. However, you can use a helper column to join multiple fields together, and use these fields like multiple criteria inside VLOOKUP. In the example below, Column B is a helper column that concatenates first and last names together with this formula:

=C5&D5 // helper column

VLOOKUP is configured to do the the same thing to create a lookup value. The formula in H6 is:

=VLOOKUP(H4&H5,B5:E13,4,0)

For details, see this example.

Note: INDEX and MATCH and XLOOKUP are more robust ways to handle lookups based on multiple criteria.

VLOOKUP and #N/A errors

If you use VLOOKUP you will inevitably run into the #N/A error. The #N/A error just means "not found". For example, in the screen below, the lookup value "Toy Story 2" does not exist in the lookup table, and all three VLOOKUP formulas return #N/A:

One way to "trap" the NA error is to use the IFNA function like this:

The formula in H6 is:

=IFNA(VLOOKUP(H4,B5:E9,2,FALSE),"Not found")

The message can be customized as desired. To return nothing (i.e. to display a blank result) when VLOOKUP returns #N/A you can use an empty string like this:

=IFNA(VLOOKUP(H4,B5:E9,2,FALSE),"") // no message

The #N/A error is useful because it tells you something is wrong. In practice, there are many reasons why you might see this error, including:

The lookup value does not exist in the table
The lookup value is misspelled, or contains extra space
Match mode is exact, but should be approximate
The table range is not entered correctly
You are copying VLOOKUP, and the table reference is not locked

More about VLOOKUP

More VLOOKUP examples
VLOOKUP videos
23 tips for using VLOOKUP

Other notes

Range_lookup controls whether value needs to match exactly or not. The default is TRUE = allow non-exact match.
Set range_lookup to FALSE to require an exact match and TRUE to allow a non-exact match .
If range_lookup is TRUE (the default setting), a non-exact match will cause the VLOOKUP function to match the nearest value in the table that is still less than value .
When range_lookup is omitted, the VLOOKUP function will allow a non-exact match, but it will use an exact match if one exists.
If range_lookup is TRUE (the default setting) make sure that lookup values in the first row of the table are sorted in ascending order. Otherwise, VLOOKUP may return an incorrect or unexpected value.
If range_lookup is FALSE (require exact match), values in the first column of table do not need to be sorted.